数式の履歴

概要

曜日の出力方法

数式項目で曜日を出す場合は次のように設定すればよい。
CASE( MOD( TODAY() - DATE(1900, 1, 7) ,7), 0, "日曜日", 1, "月曜日", 2, "火曜日", 3, "水曜日", 4, "木曜日", 5, "金曜日", 6, "土曜日", "#エラー#")

関数の前の !

数式の関数の前に ! (エクスクラメーションマーク)は、関数のNOT()と同じ意味を持つ。
例) ! ISPICKVAL( Ownership , "Other")

数式の制限

一つのオブジェクト内で、数式のリレーション先のオブジェクト数が１０を超えるとエラーになる。（イメージ的には、１０個までのレコードを参照できる）
※リレーション先のオブジェクトが同じでも、元の参照項目が別の場合は、別途カウントされる。
※数式で取得する項目が数式項目で、上位オブジェクトから値を取得している場合、そのリレーション数もカウントされる。

半角記号英数字以外の入力を許可しない

NOT(REGEX(<項目名>, "^[ !-~]*$"))

入力規則にて新規作成されたレコードのレコードタイプがAであり、項目Bに値が入っていない場合、エラーを表示する。

AND(recordType="A", ISNEW(), ISBLANK(B__c))

姓名の間に半角スペースがないかチェック

AND( NOT( ISBLANK(NAME__C)) ,NOT(REGEX(NAME__C, ".* .*")))

項目を変更させない

ISCHANGED( AAA_C )

入力された値が、本年度か来年度の4桁の半角英数字のみ許可

AND(
OR(
ISNEW(),
ISCHANGED(YEAR__C)
),
OR(
NOT(REGEX(YEAR__C, "^[0-9]{4}$")),
IF(
MONTH(TODAY()) < 4,
OR(
VALUE(YEAR__C) < YEAR(TODAY()) - 1,
VALUE(YEAR__C) > YEAR(TODAY())
),
OR(
VALUE(YEAR__C) < YEAR(TODAY()),
VALUE(YEAR__C) > YEAR(TODAY()) + 1
)
)
)
)

nameをユニークに保つ入力規則

※カスタムオブジェクトに限る
OR(
AND(ISNew(),
VLOOKUP( $ObjectType.API__c.Fields.Name , $ObjectType.API__c.Fields.Name, Name) = Name
),
AND(NOT(ISNew()),
ISChanged(Name),
VLOOKUP( $ObjectType.API__c.Fields.Name , $ObjectType.API__c.Fields.Name, Name) = Name
)
)

日付項目(Date_c)の前月の末日を表示する

例：Date__c:2012/11/25 ⇒2012/10/31

Date__c-DAY(Date__c)

日付項目*Date_c)の前々月の末日を表示する

例；Date__c:2011/1/20⇒2010/11/30

Date__c-(DAY(Date__c)+DAY(Date__c-DAY(Date__c)))

西暦から和暦への変換数式

if(
and(XXXX >=date(1868,09,08),XXXX <=date(1912,07,29)),
"明治"&text(year(XXXX)-1867)&"年"&text(month(XXXX))&" 月"&
text(day(XXXX))&"日",
if(
and(XXXX >=date(1912,07,30),XXXX <=date(1926,12,24)),
"大正"&text(year(XXXX)-1911)&"年"&text(month(XXXX))&" 月"&
text(day(XXXX))&"日",
if(
and(XXXX >=date(1926,12,25),XXXX <=date(1989,01,07)),
"昭和"&text(year(XXXX)-1925)&"年"&text(month(XXXX))&" 月"&
text(day(XXXX))&"日",
if(
XXXX >=date(1989,01,08),
"平成"&text(year(XXXX)-1988)&"年"&text(month(XXXX))&" 月"&
text(day(XXXX))&"日","#エラー"))))

*